Nach einer Idee von Tim Markwitz
Den Norton Commander hat es für VZ 200 / LASER nie
gegeben.
Wozu auch ? - Schliesslich lassen sich auf der Diskette keine
Unterverzeichnisse anlegen und maximal 120 Files könnten auf einer
Diskette gespeichert werden. Die müssten sich dann die knapp 80 KB teilen.
Wenn Du mit "DIR" das
Directory anzeigen lässt, wird es trotzdem schnell unüberschaubar,
obwohl sich die Anzeige mit der SPACE Taste anhalten lässt.
Bei mehr als 14 Einträgen verliert man zu schnell die Übersicht.
Das ändert die Maschinenroutine in diesem kleinen
BASIC Programm.
Die Einträge werden ab sofort in 3 Spalten angezeigt. Bis zu 45
Files lassen sich mit den Pfeiltasten ansteuern und mit RETURN starten
(nur B: und T: Files ). Mit
RUBOUT beim VZ, bzw. DELETE beim VZEMU können einzelne Dateien von der Diskette gelöscht werden.
Tipps :
POKE 30876,1:DIR:POKE 30876,0:LPRINT
(gibt das Directory auf dem Drucker aus, auch STATUS ist möglich)
Wird das REM in Zeile 18 gelöscht, erhält man einen
Bild Betrachter
|
Download
|
0 REM *** BY G.TILLMANNS ***
1 FOR I = 30797 TO 30844 : READ A : POKE I,A : NEXT : P = 28673
2 POKE 31170,77 : POKE 31171,120 : POKE 31169,195 : REM JP 784DH
3 POKE 30744,0 : CLS : DIR : PRINT : IF PEEK (P + 1) = 96, END : ELSE 7
4 IF PEEK (PN) = 122,P = PN : GOTO 7
5 IF PEEK (PN - 1) = 122,P = PN - 1 : GOTO 7
6 IF PEEK (PN + 1) = 122,P = PN + 1
7 GOSUB 26 : GOSUB 25 : IF K = 13, GOTO 18
8 IF K = 127,N$ = "ERA" : D$ = ":RUN" : GOTO 22
9 IF K = 10 THEN PN = P + 32 : GOTO 4
10 IF K = 32 THEN PN = P + 32 : GOTO 4
11 IF K = 27 THEN PN = P - 32 : GOTO 4
12 IF K = 46 THEN PN = P - 32 : GOTO 4
13 IF K = 9 THEN PN = P + 11 : GOTO 4
14 IF K = 44 THEN PN = P + 11 : GOTO 4
15 IF K = 8 THEN PN = P - 11 : GOTO 4
16 IF K = 77 THEN PN = P - 11 : GOTO 4
17 GOTO 7
18 REMIF PEEK(P-1)=66,N$="MODE(1):BLOAD":D$=":GOTO29":GOTO22
19 IF PEEK (P - 1) = 66,N$ = "BRUN " : GOTO 22
20 IF PEEK (P - 1) = 84,N$ = "RUN " : GOTO 22
21 GOTO 5
22 N$ = " " + N$ + CHR$ (34)
23 FOR I = 1 TO 8 : N$ = N$ + CHR$ ( PEEK (P + I)) : NEXT : N$ = N$ +
CHR$ (34)
24 CLS : PRINT : PRINT N$;D$; CHR$ (28); : END
25 POKE 30873,0 : K = PEEK (30873) : IF K = 0 THEN 25
26 FOR I = P - 1 TO P + 8 : B = PEEK (I)
27 IF B > 64,B = B - 64 : ELSE IF B < 64,B = B + 64
28 POKE I,B : NEXT : RETURN
29 POKE 30873,0 : IF PEEK (30873) = 0 THEN 29 : ELSE RUN
30 REM ** DDIR 784DH-787CH **
31 DATA 254,13,192,251,217,225,193,209,213,197,229,33,124,120,62
32 DATA 71,186,48,17,62,73,186,56,12,52,126,254,3,62,32,32,12,58
33 DATA 156,120,183,62,13,32,2,62,29,54,0,217,79,201,0